Apex Fusion Alarms

[BestMomEver]

So.... I have a question. I get alarms when the temp goes up or when the pH drops.... regular stuff. I've never worried about them cause 99% of the time its the pH. I battle low pH constantly. This morning I set up a Leak Detection Kit then left the house. I also left the heater going in the house and it was 76 degrees out today. While out I continually got alarms. I thought it was the LDK telling me there was water all over the floor... or that I had set the thing up wrong. I wasn't sure. What actually had happened was that the temp in the tank rose because of how hot the house was. It went slightly above the 80 degree limit, so the Apex cut my lights off. No big deal. It did what it was supposed to do.

But here's the problem. When I get an alarm and look at the alarm log, all it says is the date and time and that something was cut on or off. It never tells me what the problem is (except for pH). If the temp goes up, all the alarm says is that the Apex turned something off. I never know what that something is. Now that I have the LDK, I will freak out if I get an alarm because I won't know what it is.

Is there a way to change this? How do you know what is happening?

 

[BestMomEver]

Anyone? I’ve gotten 29 pages of alerts today...

 

[ca1ore]

I set up virtual outlets for alerts. So, something like temp_high where:

FALLBACK OFF
SET OFF
If temp > 80 Then ON
Defer 001:00 Then ON

Put ‘If output temp_high on Then on’ into your email alert and it’ll show what triggered the alert. Or just have temp_high s a tile on fusion and you can easuliy scan the dashboard to identify the offender.

 

[Tastee]

The alert email and the alert in the Fusion log will show the line of code in the EmailAlert outlet that triggered the alarm. It’s important to understand that the Apex is a form of a state machine. The code for the EmailAlert outlet will be parsed every second and when the state changes from OFF to ON an alert will be generated, which will quote the last line of code that changed the outlet to ON.

If multiple commands turn the alarm ON then only the last will be quoted.

So it is important to sequence your code from least important to most important. Here is my code as an example. The last line (defer) is to ensure an alert is on for a minimum of 2 seconds before an alert is issued.

Set OFF
If Tmp > 26.8 Then ON
If Tmp < 24.9 Then ON
If Power Apex OFF 000 Then ON
If Outlet PowerOutage = ON Then ON
If Outlet PowerOutLong = ON Then ON
If Power EB6_1 OFF 001 Then ON
If Error ATOPump Then ON
If ATOHi CLOSED Then ON
If FlrLk CLOSED Then ON
If Outlet SumpLow = ON Then ON
Defer 000:02 Then ON

Another alert will be issued when the EmailAlert outlet changes from ON to OFF. In this case the line quoted will be the last statement that set it to OFF. In my example this will always be the first line.

 

[BestMomEver]

The alert email and the alert in the Fusion log will show the line of code in the EmailAlert outlet that triggered the alarm. It’s important to understand that the Apex is a form of a state machine. The code for the EmailAlert outlet will be parsed every second and when the state changes from OFF to ON an alert will be generated, which will quote the last line of code that changed the outlet to ON.

If multiple commands turn the alarm ON then only the last will be quoted.

So it is important to sequence your code from least important to most important. Here is my code as an example. The last line (defer) is to ensure an alert is on for a minimum of 2 seconds before an alert is issued.

Set OFF
If Tmp > 26.8 Then ON
If Tmp < 24.9 Then ON
If Power Apex OFF 000 Then ON
If Outlet PowerOutage = ON Then ON
If Outlet PowerOutLong = ON Then ON
If Power EB6_1 OFF 001 Then ON
If Error ATOPump Then ON
If ATOHi CLOSED Then ON
If FlrLk CLOSED Then ON
If Outlet SumpLow = ON Then ON
Defer 000:02 Then ON

Another alert will be issued when the EmailAlert outlet changes from ON to OFF. In this case the line quoted will be the last statement that set it to OFF. In my example this will always be the first line.

Ok... so I apologize in advance.... what I have done is put the first sensor next to the skimmate container. I want the skimmer to shut off if it overflows. What do I ask it?

I have the other sensor on the floor. If it detects water, I want the return pump and skimmer to shut off. What code do I use here?

As far as my dashboard, it shows the link slider along with each sensor slider. I don’t know if I should have all of them or some of them. I also have the sliders for alerts. Don’t know if I need them either. As for alerts, I want a notification if pH is low/high and I want a notification if the temp goes low/high. For the leak detection, I want a notification and an audible alarm. All the extraneous stuff just confuses me.

Basically.... will you configure it for me? ;Sorry I’m technologically challenged.

 

[BestMomEver]

I also want to know if there’s a power outage and I want the skimmer to stay off when the power comes back on.

 

[Tastee]

It’s a little difficult to answer those questions directly as I can’t see your setup. It does sound like you are doing a lot of what I have done. I don’t have a leak kit but use the FMM which is very similar. Here is a screenshot of my dashboard and my code, hopefully this will help you setup what you need.

I do have this setup for power outage detection, and my Apex EB6 is powered by a UPS. I then have an AC adapter connected to mains power connected to the Apex main unit. This means in a power outage my Apex stays on (as it is powered by the EB6) but it detects the outage via the AC adapter. Search for Apex Power Outage configuration and you should find lots of posts describing how to set this up.

Here is my full program (apart from what I just configure using the wizards). The comments and outlet labels are just for my reference and don’t get put into the actual apex.

[ATOPump]
# Outlet for the ATO Pump connected to the FMM
# No point trying to run this during a power outage as the PMUP is powered from mains power
#
Fallback OFF
Set OFF
If ATOLo OPEN Then ON
If ATOHi CLOSED Then OFF
When On > 020:00 Then OFF
If Time 13:00 to 11:59 Then OFF
If Outlet PowerOutage = ON then OFF
Defer 000:10 Then ON
Defer 000:04 Then OFF
Min Time 120:00 Then OFF

[AutoFeeder]
Set OFF
If Outlet V-Feed = ON then ON
Defer 1:00 then ON

[Chiller]
# Chiller is controlled by it’s internal thermostat, so this is just a backup in case that thermostat fails.
Fallback ON
If Tmp > 25.0 Then ON
If Tmp < 24.8 Then OFF
If Outlet PowerOutage = ON then OFF

[EmailAlert]
Set OFF
If Tmp > 26.8 Then ON
If Tmp < 24.9 Then ON
If Power Apex OFF 000 Then ON
If Outlet PowerOutage = ON Then ON
If Outlet PowerOutLong = ON Then ON
If Power EB6_1 OFF 001 Then ON
If Error ATOPump Then ON
If Error ChillerAlert Then ON
If ATOHi CLOSED Then ON
If FlrLk CLOSED Then ON
If Outlet SumpLow = ON Then ON
Defer 000:02 Then ON

[MainHeater]
Fallback OFF
If Tmp < 25.0 Then ON
If Outlet PowerOutage = ON then OFF
If Tmp < 20.0 then ON
Defer 000:20 Then ON
If Tmp > 25.2 Then OFF
Defer 000:20 Then OFF

[PowerOutage]
# VO to indicate a power outage
# Strictly speaking this is redundant but it improves the readability of other code
#
Set OFF
If Power Apex OFF 001 Then ON

[PowerOutLong]
# VO to indicate a power outage has gone beyond the first threshold
# Used to turn off/reduce use of less important devices to extend life of the UPS
#
Set OFF
If Outlet PowerOutage = ON then ON
Defer 030:00 Then ON

[ReturnPump]
Fallback ON
OSC 000:00/005:00/010:00 Then ON
If Outlet PowerOutLong = OFF Then ON
If FeedA 000 Then OFF
If FeedB 000 Then OFF
If Outlet V-Feed = ON Then OFF

[Skimmer]
Fallback OFF
Set ON
If Outlet ReturnPump = OFF Then OFF
If FeedB 000 Then OFF
Defer 1:00 Then ON

[SumpLow]
# VO to detect if the sump water level is low
#
Set OFF
If SumpLo OPEN Then ON
Defer 001:00 Then ON

[V-Feed]
Set OFF
If Time 19:00 to 19:09 Then ON

[WaveMaker]
Fallback ON
OSC 000:00/005:00/010:00 Then ON
If Outlet PowerOutLong = OFF Then ON
If FeedA 001 Then OFF
If FeedB 000 Then OFF