Apex Controller....... oh the things you can do!! ** Discussion Thread **

[Stpatrick]

Pump1
Fallback ON
OSC 000:00/000:10/000:10 Then ON


Pump2
Fallback ON
If Outlet Pump1 = ON then OFF


CJ

Your the man

 

[Stpatrick]

Pump1
Fallback ON
OSC 000:00/000:10/000:10 Then ON


Pump2
Fallback ON
If Outlet Pump1 = ON then OFF


CJ

does that code have one pump on for 10 secs then the next?

 

[CJO]

does that code have one pump on for 10 secs then the next?

Yes. The first one uses the OSC command to turn the pump ON for 10 seconds and then OFF for 10 seconds. The second pump is ON unless the first one is ON.

CJ

 

[ToXIc]

Ok dumb questions..
1: Did they stop selling/packaging the PM1 module with the $500 systems?
2: My base module has the V1/V2 and V3/V4 ports does this mean when I do my LED build I won't have to buy a VDM?

 

[CJO]

Not sure about the PM1 module. If you bought the Apex (not light), it has the variable output ports on it and you don't need to buy the VDM to control your DIY LEDs (you would if you are buying an Aqua Illumination LED system).

CJ

 

[ToXIc]

Not sure about the PM1 module. If you bought the Apex (not light), it has the variable output ports on it and you don't need to buy the VDM to control your DIY LEDs (you would if you are buying an Aqua Illumination LED system).

CJ

awesome news that saved me $100

 

[CJO]

I'll PM you my paypal address

CJ

 

[ToXIc]

I'll PM you my paypal address

CJ

lawls....

 

[lps1212]

Mines controls cameras for viewing of my tank controls the chiller lights and mp's monitors the ph orp temp. But what I like about it most is that it turns on the coffee pot starts up my car and even does dvr on my Deadliest Catch show and Dual Survivor :snicker::waaaht:

 

[ToXIc]

Mines controls cameras for viewing of my tank controls the chiller lights and mp's monitors the ph orp temp. But what I like about it most is that it turns on the coffee pot starts up my car and even does dvr on my Deadliest Catch show and Dual Survivor :snicker::waaaht:

clown..

i was contemplating the chiller.. but i was thinking should the chiller stay on instead of being turn on and off constantly, i've got the 1/4hp JBJ Artica Titanium Chiller DBA-200 that comes on automatically according to the temp of the water running trough it..

 

[lps1212]

clown..

i was contemplating the chiller.. but i was thinking should the chiller stay on instead of being turn on and off constantly, i've got the 1/4hp JBJ Artica Titanium Chiller DBA-200 that comes on automatically according to the temp of the water running trough it..

lol had to couldn't help myself but on a serious note I have mines set to go on if temp reaches 82 and shut off at 75 but very rarely does it go on since my central air keeps the house at a steady 70 :cold:

 

[CJO]

I would keep using the chiller's built-in temperature sensor, but use the Apex as a fail-safe.

CJ

 

[ToXIc]

ok R2R i want to compile some programming examples for the main thread..

Calcium Rx (will be either ph or ph2 depending on which probe you're using for the Rx)

Fallback OFF
Set OFF
If pH2 > 06.90 Then ON
If pH2 < 06.60 Then OFF
If Outlet pH2 = OFF Then OFF

Lights (note change "xx" to what temp you want)

Fallback OFF
Set OFF
If Time 09:00 to 22:00 Then ON
If Temp > xx.0 Then OFF
Min Time 030:00 Then OFF

Return Pumps

Fallback ON
Set ON
If FeedA 015 Then OFF
If FeedB 030 Then OFF

Heater

Fallback OFF
Set OFF
If Temp < 76.0 Then ON
If Temp > 78.0 Then OFF

Email Alarm

Set OFF
If Temp > 85.0 Then ON
If Temp < 75.0 Then ON
If pH > 08.50 Then ON
If pH < 07.80 Then ON

 

[CJO]

Here are some of mine. I've added comments to the programming after the semicolons

White LED variable output

Fallback OFF
Set OFF
If Sun 120/000 Then W_Sun; uses W_Sun profile to dim LEDs over 2 hours for sunrise and sunset that changes with the seasons. It's delayed 2 hours from actual sunrise/sunset
If Outlet W_On = ON Then ON; high noon effect
If Outlet LED_10K = ON Then LED_100; changes lighting for 10,000K look if variable is set
If Outlet LED_14K = ON Then LED_100; changes lighting for 14,000K look if variable is set
If Outlet LED_20K = ON Then LED_50; changes lighting for 20,000K look if variable is set

White LED power outlet

Fallback OFF
Set OFF
If Sun 120/119 Then ON
If Power Apex Off 015 Then OFF; turns off lights if power is off for longer than 15 minutes

Blue LED variable outlet

Fallback OFF
Set OFF
If Sun 090/120 Then B_Sun; uses B_Sun profile to dim LEDs over 30 minutes for sunrise and sunset that changes with the seasons. It's delayed 2 hours from actual sunrise/sunset
If Outlet B_On = ON Then ON; keeps LEDs on at 100% after sunrise
If Outlet LED_10K = ON Then LED_50; changes lighting for 10,000K look if variable is set
If Outlet LED_14K = ON Then LED_100; changes lighting for 14,000K look if variable is set
If Outlet LED_20K = ON Then LED_100; changes lighting for 20,000K look if variable is set

Blue LED power outlet

Fallback OFF
Set OFF
If Sun 090/134 Then ON
If Power Apex Off 015 Then OFF; turns off lights if power is off for longer than 15 minutes

Outlet W_On; variable outletto let the white LED dimmer know when to have it on 100% (noon effect)

If Sun 240/000 Then ON

Outlet B_On; variable outlet to let the blue LED dimmer konw when to have it on 100%

If Sun 105/120 Then ON

Heater outlet

Fallback OFF
Set OFF
If Temp < RT+-1.0 Then ON
If Temp < 40.0 Then OFF; temp sensor normally reads 20 degrees when it fails

Skimmer outlet

Fallback ON
Set ON
If Power Apex Off 001 Then OFF; turns skimmer off if power has been off longer than a minute
If Outlet Return_Pump = OFF Then OFF; turns skimmer off if return pump is off
If Outlet Skimmer_Full = ON Then OFF; turns off if skimmer cup is full
If Outlet ATO = ON Then OFF; turns off when ATO is on (kalk in ATO sometimes makes it overflow)
If FeedA 060 Then OFF
If FeedB 060 Then OFF
If FeedC 010 Then OFF
If FeedD 010 Then OFF
Defer 005:00 Then ON; stays off for at least 5 minutes

AutoFeeder

Set OFF
Fallback OFF
If Time 13:00 to 13:05 Then ON; turns on feeder every day at 1:00pm

Fan

Fallback OFF
Set OFF
If Temp > RT+1.0 Then ON; turns on fan if temp is more than 1 degree over seasonal temp
Min Time 010:00 Then OFF; keeps fan on for at least 10 minutes

ATO; topoff water pump.. note that topoff water contains KALK

Fallback OFF
OSC 000:00/002:00/005:00 Then ON; turns on ATO every 5 minutes for 2 minutes unless one of the following is true
If Outlet Water_Low = OFF Then OFF; if water in sump is at proper level it doesn't turn on
If FeedC 000 Then OFF; if cleaning tank it doesn't turn on
If Outlet Return_Pump = OFF Then OFF; if the return pump is off it doesn't turn on
If Outlet Water_High = ON Then OFF; if the high water failsafe switch is on it doesn't turn on
IIf pH > 8.50 Then OFF; if sumps pH is over 8.5 it doesn't turn on
Min Time 002:00 Then ON; keeps it on for at least 2 minutes

Vortech master; Vortech MP10wES controlled by through the WXM

Set Nutrient; normal mode is nutrient export
If Time 08:00 to 10:00 Then ReefCrst; run reef crest for 2 hours in the morning
If Time 19:00 to 21:00 Then ReefCrst; run reef crest for 2 hours in the evening
If Time 21:30 to 06:00 Then Night; night mode at night
If Outlet Feeder = ON Then ON; if autofeeder is on, put on pumps at 100% so they have to chase food
If FeedA 000 Then Nutrient
If FeedB 000 Then ON
If FeedC 000 Then OFF
If FeedD 000 Then Nutrient
If Power Apex Off 000 Then Night; if power goes out, pumps lower to 50% power

Vortech slave; Vortech MP10wES controlled by through the WXM

Set Sync; normally is in sync mode with master pump to create waves
If Time 08:00 to 08:05 Then AntiSync; change it up to antisync a few times a day for random water motion
If Time 17:30 to 18:35 Then AntiSync
If Time 20:30 to 21:35 Then AntiSync
If Outlet Feeder = ON Then ON
If FeedA 000 Then Slow
If FeedB 000 Then ON
If FeedC 000 Then OFF
If FeedD 000 Then Sync

Email; sends an email and text if one of the following happens

Fallback OFF
Set OFF; outlet is normally off
If Outlet Water_Low = ON Then ON; if water in sump is low
If Time 23:00 to 06:30 Then OFF; does not text or email when I'm asleep!
If Temp > RT+2.0 Then ON; sends if temperature is more than 2 degrees over seasonal temp
If Temp < RT+-2.5 Then ON ; sends if temperature is lower than 2.5 degrees below seasonal temp
If Temp > 82.5 Then ON; sends if temp is greater than 82.5
If pH < 07.70 Then ON; sends if pH is too low
If pH > 08.70 Then ON; sends if pH is too high
If ORP < 200 Then ON; sends if ORP is too low
If ORP > 500 Then ON; sends if ORP is too high
If Power EB8_3 Off 000 Then ON; sends if power goes out
If Power Apex Off 000 Then ON; sends if power goes out
If FeedC 000 Then OFF; overrides the previous if I'm cleaning tank
Defer 010:00 Then ON; state must be in ON position for more than 10 minutes before warning is sent
If Temp < 40.0 Then ON; sends if temperature probe has failed
If Outlet Water_High = ON Then ON; sends if sump is near overflowing
If Outlet Skimmer_Full = ON Then ON; sends if skimmer cup is full

Hope this helps,
CJ

 

[ToXIc]

please elaborate on the following terms and values..

If Temp < RT+-1.0 Then ON

If Sun 120/119 Then ON

whats RT and Sun and the values..

 

[Salty Dog]

I was thinking of getting the Proflux, should I just go with the Apex

 

[ToXIc]

Not sure what the proflux has to offer but you can't go wrong with an apex unit.


____________________________
Sent from my iThingy using Tapatalk

 

[gnoles]

Sorry one of the mods thought it was a double thread. I have moved it back.

I just sold my RKE and got an apex so I have questions.

1. My new skimmer has a float switch built in, but it is just two naked wires on the end. How would I use that with my apex? Is there something I need to buy?

I use the IO Breakout box. Then with various float switches (including the skimmer cup) I take care of my skimmer, ATO container low condition, sump low and high conditions.

Any of these will turn on the sump light for me during the day and turn it off during the night. I'm considering having it email me when the skimmer cup is full, because it's an unusual condition that usually happens when we have a power failure, come to think of it, I'm going to add a condition to keep the skimmer off when the Sump High condition is active.

Skimmer

Fallback OFF
Set ON
If FeedA 005 Then OFF
If FeedB 015 Then OFF
If FeedC 015 Then OFF
If FeedD 015 Then OFF
If Outlet SkimmerCup = ON Then OFF
If Outlet SumpHigh = ON Then OFF
If Power Apex Off 010 Then ON
If Power EB8_3 Off 010 Then ON
If Power EB8_4 Off 010 Then ON

SumpHigh

Fallback OFF
Set OFF
If Switch3 CLOSED Then ON

 

[CJO]

please elaborate on the following terms and values..
whats RT and Sun and the values..

The Apex has the ability to vary these values with the seasons. RT stands for Reef Temp and is the average temperature of the reef for the current day. SUN refers to the actual sunrise and sunset times for the same reef for the current day.

I use them to introduce some natural variability to my tank. Rather than having the temperature stay the same all day, every day, I have it warmer in the summers and cooler in the winters. Also, instead of having the lights turn on and off at the same time every day, they are varied so that they are longer in the summer and shorter in the winter.

CJ

 

[CJO]

I was thinking of getting the Proflux, should I just go with the Apex

When I was looking at controllers, the Profilux was considered the top of the line, but I couldn't afford it so I got the Apex. I'm not sure how much it's changed since then.

CJ